mirror of
https://github.com/pentoo/pentoo-overlay
synced 2025-12-06 08:25:01 +01:00
48 lines
1.3 KiB
Bash
48 lines
1.3 KiB
Bash
# Copyright 1999-2019 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DESCRIPTION="Library for cross-platform C path functions"
|
|
HOMEPAGE="https://github.com/libyal/libcpath"
|
|
SRC_URI="https://github.com/libyal/libcpath/releases/download/${PV}/${PN}-alpha-${PV}.tar.gz"
|
|
|
|
LICENSE="LGPL-3"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 ~arm64 x86"
|
|
IUSE="nls unicode debug"
|
|
|
|
DEPEND="
|
|
dev-libs/libcerror[nls=]
|
|
dev-libs/libclocale[nls=,unicode=]
|
|
dev-libs/libcsplit[nls=,unicode=]
|
|
dev-libs/libuna[nls=,unicode=]
|
|
nls? (
|
|
virtual/libiconv
|
|
virtual/libintl
|
|
)
|
|
"
|
|
RDEPEND="${DEPEND}"
|
|
|
|
src_configure() {
|
|
econf \
|
|
$(use_enable nls) \
|
|
$(use_with nls libiconv-prefix) \
|
|
$(use_with nls libintl-prefix) \
|
|
$(use_enable unicode wide-character-type) \
|
|
$(use_enable debug verbose-output) \
|
|
$(use_enable debug debug-output)
|
|
|
|
# --disable-shared-libs disable shared library support
|
|
# not supported in the ebuild at the moment - kind of defeats the entire process
|
|
|
|
# --enable-winapi enable WINAPI support for cross-compilation
|
|
# [default=auto-detect]
|
|
# not supported in the ebuild at the moment - requires windows.h, does not make much sense for us
|
|
}
|
|
|
|
src_install() {
|
|
default
|
|
# see https://projects.gentoo.org/qa/policy-guide/installed-files.html#pg0303
|
|
find "${ED}" -name '*.la' -delete || die
|
|
}
|