mat2: bump to 0.10.1

app-misc/mat2/Manifest

@@ -1 +1,2 @@
 DIST mat2-0.10.0.tar.gz 5720611 BLAKE2B 3aeb1b5fb1e5b39d5a59e84de48a1fefed8afff31d7ae2827324b9d54eab8a95f28f0e1de94d6c96ba250249531782f4a2cff4a82fdccc85da7382d00294fdaf SHA512 7434365766f5ba893b5b51e852d73af6b1dd562f3804e46b2aa5bf2097694d5465f0ddb5e401b157ed899a86caca2dd405424c5a7c86d66190cefd30eee3ba65
+DIST mat2-0.10.1.tar.gz 5780327 BLAKE2B d8ffeb1c10409aa4fb93849e641c13bb65508441fb847db2a46f289becd33a160ac711c3c3fb302bfbacd5704acc9b15876a182916cf3d34bf8bb867836fe6b4 SHA512 ee6ec621b3e98cfcf2f341364f60d853be8aedbee88fd41d2cc97888ba7ee33f7610f165cdf140e0169fbdabd41ecafe80a30dab44dc9f2b1cb501973a8e403a

app-misc/mat2/mat2-0.10.1.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="xml"
+
+inherit desktop distutils-r1 xdg-utils
+
+DESCRIPTION="A handy tool to trash your metadata"
+HOMEPAGE="https://0xacab.org/jvoisin/mat2"
+SRC_URI="https://0xacab.org/jvoisin/mat2/-/archive/${PV}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="GPL-3"
+SLOT="0"
+
+IUSE="dolphin ffmpeg +exif nautilus test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	test? ( exif ffmpeg )"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	app-text/poppler[introspection,cairo]
+	dev-libs/glib
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	exif? ( media-libs/exiftool )
+	gnome-base/librsvg:2[introspection]
+	ffmpeg? ( virtual/ffmpeg )
+	media-libs/mutagen[${PYTHON_USEDEP}]
+	nautilus? ( dev-python/nautilus-python )
+	x11-libs/gdk-pixbuf[introspection,jpeg,tiff]"
+
+distutils_enable_tests unittest
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use nautilus; then
+		insinto /usr/share/nautilus-python/extensions/
+		doins nautilus/mat2.py
+	fi
+
+	if use dolphin; then
+		insinto /usr/share/kservices5/ServiceMenus/
+		doins dolphin/mat2.desktop
+	fi
+
+	doicon -s 512 data/mat2.png
+	doicon -s scalable data/mat2.svg
+
+	doman doc/mat2.1
+	dodoc *.md doc/*.md
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}