fern-wifi-cracker: 3.1 bump

net-wireless/fern-wifi-cracker/Manifest

@@ -1 +1,2 @@
 DIST fern-wifi-cracker-3.0.tar.gz 739360 BLAKE2B dc5b5131276ed6defb6eb332ccd3b249d0234d712f0658fead4c41da7d93a2813e59ac8ffbd85ec95ce3160ee67271d9be2c8c92b46b41e00c0956f6c8fffd4a SHA512 e104b9aed517ffd158c83bda24f2496cbb33eeb4b54adfe0963a7d176cadacd374b495fd3f2d936d4e32f28c96831957ddbd264f8bfe9d9a8e181f139ef4e98a
+DIST fern-wifi-cracker-3.1.tar.gz 1604777 BLAKE2B 39da7292a63ae9aebd0c6d370e0025b171a329dae2202f310fe89f563371982666bc4167ba54ddae10d205fafd328fba9ea21cbad97d93a3456e528fdb93cb15 SHA512 4be5cbc0b3b41c7ccc9f907092a5341f88eeb4a7d39301e148cb73477d6cfb5abe0f18aca48854e37e1a4a41b616b8f32c5b2ab88a60c4392bc1bfd1caea3947

net-wireless/fern-wifi-cracker/fern-wifi-cracker-3.1.ebuild

@@ -0,0 +1,90 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="sqlite"
+
+inherit eutils desktop python-single-r1 xdg-utils
+
+DESCRIPTION="Wireless tool for WEP/WPA cracking and WPS keys recovery"
+HOMEPAGE="https://github.com/savio-code/fern-wifi-cracker"
+SRC_URI="https://github.com/savio-code/fern-wifi-cracker/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dict policykit"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/PyQt5[gui,widgets,${PYTHON_MULTI_USEDEP}]
+		>=net-analyzer/scapy-2.4.3[${PYTHON_MULTI_USEDEP}]
+	')
+	net-analyzer/macchanger
+	net-wireless/aircrack-ng
+	dict? ( sys-apps/cracklib-words )
+	|| ( net-wireless/reaver-wps-fork-t6x net-wireless/reaver )
+	policykit? ( sys-auth/polkit )"
+
+S="${WORKDIR}/${P}/Fern-Wifi-Cracker"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# disable updates
+	sed \
+		-e "s|self.connect(self.update_button|#self.connect(self.update_button|" \
+		-i core/fern.py || die
+	sed \
+		-e "s|thread.start_new_thread(self.update_initializtion_check|#thread.start_new_thread(self.update_initializtion_check|" \
+		-i core/fern.py || die
+
+	python_fix_shebang "${S}"
+
+	default
+}
+
+src_install() {
+	insinto "/usr/share/fern-wifi-cracker"
+	doins -r *
+	python_optimize "${ED}/usr/share/fern-wifi-cracker"
+
+	dosym "../fern-wifi-cracker/resources/icon.png" "/usr/share/pixmaps/${PN}.png"
+
+	make_wrapper $PN \
+		"${EPYTHON} /usr/share/fern-wifi-cracker/execute.py"
+
+	if use policykit; then
+		insinto "/usr/share/polkit-1/actions/"
+		doins "${FILESDIR}"/com.fern-pro.pkexec.fern-wifi-cracker.policy
+
+		make_desktop_entry \
+			"pkexec /usr/bin/${PN}" \
+			"Fern Wifi Cracker" \
+			"${PN}" \
+			"System;Security;X-Pentoo;X-Penetration;X-Wireless;"
+	else
+		make_desktop_entry \
+			"$PN" \
+			"Fern Wifi Cracker" \
+			"$PN" \
+			"System;Security;X-Pentoo;X-Penetration;X-Wireless;"
+	fi
+
+	dodoc ../README.md
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}