testssl-3.0.9.ebuild

net-analyzer/testssl/Manifest

@@ -1,2 +1,3 @@
 DIST testssl-3.0.8.tar.gz 9372229 BLAKE2B cf463236fb0812c2bc5fd5673d0d2d395fc405697817827ee8c660c96d789601a090b57febd48400e33fd9f28b23d42d432734b176b23a8e8ddf710c9b275485 SHA512 4634bc5dc57ad8910ca097b22d86511a26e855fb4dc7bef9550a795cb1f53a959b8472008756b40a670d7433ad56236b5a36fe0c88c15de99fdf586e9919b080
+DIST testssl-3.0.9.tar.gz 9381651 BLAKE2B 424569411022b68f105a20ad5b60db7c8994d1170482612ae7aed741230bd3fca43cd853dfb00660d5ba7cfdc717fa887a2fe9b6c59bbcef881f8f6473ccad3e SHA512 006180d175492f1cba6d056a92a57247725d4b68cddbebeea80a5d339d542f5103ddc8226f3a554775cb83bbef836a5d5bfc1bcf4fba7b18b9541473122ff720
 DIST testssl-3.2_rc3.gh.tar.gz 9448376 BLAKE2B 76d62c140c0a3763aec80c7073473d114af9520e37db719f131cffcc3b5d4ab258d4d6d08e8911a3adbd11b69c91677b295974f5238a3aeaf71212b99e95e1a4 SHA512 716d68796ebdecc7549b09bffbc8d5907eb40de16de3c09760bf61c3d33523d94535ca01dbe2ce891abe4c96001edb878d01ef9414b51aa93168304fd7480dbb

net-analyzer/testssl/testssl-3.0.9.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Tool to check TLS/SSL cipher support"
+HOMEPAGE="https://testssl.sh/"
+SRC_URI="https://github.com/drwetter/testssl.sh/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 bundled-openssl? ( openssl )"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 x86"
+IUSE="bundled-openssl kerberos"
+REQUIRED_USE="bundled-openssl? ( || ( amd64 x86 ) )"
+
+# openssl-bad provides 197 ciphers
+# bundled-openssl has 183 ciphers
+# openssl (gentoo) 80 ciphers only
+RDEPEND="
+	app-shells/bash[net]
+	net-dns/bind-tools
+	sys-apps/util-linux
+	sys-libs/ncurses:0
+	sys-process/procps
+	bundled-openssl? (
+		kerberos? (
+			sys-libs/zlib
+			virtual/krb5
+		)
+	)
+	!bundled-openssl? ( dev-libs/openssl-bad )"
+
+S="${WORKDIR}/testssl.sh-${PV}"
+
+QA_PREBUILT="opt/${PN}/*"
+
+pkg_setup() {
+	if use amd64; then
+		if use kerberos; then
+			BUNDLED_OPENSSL="openssl.Linux.x86_64.krb"
+		else
+			BUNDLED_OPENSSL="openssl.Linux.x86_64"
+		fi
+	elif use x86; then
+		BUNDLED_OPENSSL="openssl.Linux.i686"
+	fi
+}
+
+src_prepare() {
+	default
+	sed -i ${PN}.sh \
+		-e 's|TESTSSL_INSTALL_DIR="${TESTSSL_INSTALL_DIR:-""}"|TESTSSL_INSTALL_DIR="/"|' \
+		-e 's|$TESTSSL_INSTALL_DIR/etc/|&testssl/|g' || die
+
+	#Gentoo hack find_openssl_binary(), we do it better
+	if use bundled-openssl; then
+		sed -i ${PN}.sh \
+			-e "s|OPENSSL=\"\$1/openssl\"|OPENSSL=\"/opt/${PN}/${BUNDLED_OPENSSL}\"|" || die
+	else
+		sed -i ${PN}.sh \
+			-e 's|OPENSSL="$1/openssl"|OPENSSL="$1/openssl-bad"|' || die
+	fi
+}
+
+src_install() {
+	dodoc CHANGELOG.md CREDITS.md Readme.md
+	dodoc openssl-iana.mapping.html
+
+	dobin ${PN}.sh
+
+	insinto /etc/${PN}
+	doins etc/*
+
+	if use bundled-openssl; then
+		exeinto /opt/${PN}
+		use amd64 && doexe bin/${BUNDLED_OPENSSL}
+	fi
+}