pillow: fork, fixing https://bugs.gentoo.org/895948

dev-python/pillow/Manifest

@@ -0,0 +1 @@
+DIST pillow-9.4.0.gh.tar.gz 50412873 BLAKE2B 12003b8b9e582c47b45d82f4a10553e376dcb38e65154eca5753b2908d6ecad10fc732d622856c7742fb413abbf4afc926e3d30e1e9e410e966f18da4ddde6c1 SHA512 6c08336e5ca1e652bb3237ae092be61b78dc1cf65603d6b23369eb8e0554786114a8f87ab092a5fb9577e02cd0bb381353fa657e03090baeb91b4b8e3c740d51

dev-python/pillow/pillow-9.4.0-r1.ebuild

@@ -0,0 +1,133 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+PYTHON_REQ_USE='tk?,threads(+)'
+
+inherit distutils-r1 toolchain-funcs virtualx
+
+MY_PN=Pillow
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python Imaging Library (fork)"
+HOMEPAGE="
+	https://python-pillow.org/
+	https://github.com/python-pillow/
+	https://pypi.org/project/Pillow/
+"
+SRC_URI="
+	https://github.com/python-pillow/Pillow/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
+IUSE="examples imagequant +jpeg jpeg2k lcms raqm test tiff tk truetype webp xcb zlib"
+REQUIRED_USE="test? ( jpeg jpeg2k tiff truetype )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	imagequant? ( media-gfx/libimagequant:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpeg2k? ( media-libs/openjpeg:2= )
+	lcms? ( media-libs/lcms:2= )
+	raqm? ( media-libs/libraqm:= )
+	tiff? ( media-libs/tiff:=[jpeg,zlib] )
+	truetype? ( media-libs/freetype:2= )
+	webp? ( media-libs/libwebp:= )
+	xcb? ( x11-libs/libxcb )
+	zlib? ( sys-libs/zlib:= )
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/olefile[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		${RDEPEND}
+		dev-python/defusedxml[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		|| (
+			media-gfx/imagemagick[png]
+			media-gfx/graphicsmagick[png]
+		)
+	)
+"
+
+EPYTEST_DESELECT=(
+	# TODO; incompatible Qt version?
+	Tests/test_qt_image_qapplication.py::test_sanity
+)
+
+usepil() {
+	usex "${1}" enable disable
+}
+
+python_configure_all() {
+	# It's important that these flags are also passed during the install phase
+	# as well. Make sure of that if you change the lines below. See bug 661308.
+
+	cat >> setup.cfg <<-EOF || die
+		[build_ext]
+		disable_platform_guessing = True
+		$(usepil truetype)_freetype = True
+		$(usepil jpeg)_jpeg = True
+		$(usepil jpeg2k)_jpeg2000 = True
+		$(usepil lcms)_lcms = True
+		$(usepil raqm)_raqm = True
+		$(usepil tiff)_tiff = True
+		$(usepil imagequant)_imagequant = True
+		$(usepil webp)_webp = True
+		$(usepil webp)_webpmux = True
+		$(usepil xcb)_xcb = True
+		$(usepil zlib)_zlib = True
+	EOF
+
+	# setup.py won't let us add the right toolchain paths but it does
+	# accept additional ones from INCLUDE and LIB so set these. You
+	# wouldn't normally need these at all as the toolchain should look
+	# here anyway but it doesn't for this setup.py.
+	export \
+		INCLUDE="${ESYSROOT}"/usr/include \
+		LIB="${ESYSROOT}"/usr/$(get_libdir)
+
+	# We have patched in this env var.
+	tc-export PKG_CONFIG
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO (is clipboard unreliable in Xvfb?)
+		Tests/test_imagegrab.py::TestImageGrab::test_grabclipboard
+	)
+
+	"${EPYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
+	# no:relaxed: pytest-relaxed plugin make our tests fail. deactivate if installed
+	epytest -p no:relaxed || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	python_doheader src/libImaging/*.h
+	distutils-r1_python_install
+}
+
+python_install_all() {
+	if use examples ; then
+		docinto example
+		dodoc docs/example/*
+		docompress -x /usr/share/doc/${PF}/example
+	fi
+	distutils-r1_python_install_all
+}

media-libs/libraqm/Manifest

@@ -0,0 +1 @@
+DIST libraqm-0.10.0.tar.gz 297266 BLAKE2B 2dd561775a37ac4c98deda769a96172a801806a3f16e16bdecbbd8262bf1b8fbc22defc0841b5086b723a44366eb49c3e224ece62058337faae687fe46aa379f SHA512 741ccea508049ad55e41f65f9cdcdb08d92eccbc6860302011e4b760e1cdd1c65fc513786b5121ef02bbec5a2004b1fd79b461848d599f4ba817f2f8805642e2

media-libs/libraqm/libraqm-0.10.0.ebuild

@@ -0,0 +1,39 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ -z ${PV%%*9999} ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/HOST-Oman/${PN}.git"
+else
+	SRC_URI="https://github.com/HOST-Oman/libraqm/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64 ~x86"
+fi
+inherit meson
+
+DESCRIPTION="A library for complex text layout"
+HOMEPAGE="https://github.com/HOST-Oman/libraqm"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="gtk-doc"
+
+RDEPEND="
+	media-libs/freetype:2
+	media-libs/harfbuzz:=
+	dev-libs/fribidi
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	gtk-doc? ( dev-util/gtk-doc )
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+	)
+	meson_src_configure
+}