diff --git a/net-wireless/fern-wifi-cracker/Manifest b/net-wireless/fern-wifi-cracker/Manifest
index 36b85ed93..644b4b607 100644
--- a/net-wireless/fern-wifi-cracker/Manifest
+++ b/net-wireless/fern-wifi-cracker/Manifest
@@ -1,2 +1 @@
-DIST fern-wifi-cracker-2.7.tar.gz 748678 BLAKE2B 57af55dba8bd1842b0138c79c3f5cd3ebdbadd69bcfc69c3ad9e5b7c4d081c69dc6e36210ae4c61f6886714acd803f9eeee2c813adcff528e538ae4514b4d03c SHA512 d574a73d1b2074f13c1ef949eb8de0ba3036f067b821732b6316cf7d5b1f6d34efb3acb68395049f03ada8e5d0bce1eddf8bb8f9ef11ce5ccc3748bb31478bba
-DIST fern-wifi-cracker-2.8.tar.gz 738817 BLAKE2B a6a84f5aa824b1ec00212226e98fffb3a4967020efbb0246b41f0c360a34c95c0efbcb540a504454c4077904e27b086fc4d412c05d8f8ed40e18348700317730 SHA512 b0a6cecf5a1e0198255e8676aa69601c0078b3a7f80c4b053909f1a16875bcbc6e1dfbbbfde9f89d3ddf03c6814dd1a363ba0441d629a4d7a322c287112b528c
+DIST fern-wifi-cracker-2.9.tar.gz 739349 BLAKE2B 1e3eef80b9a58778eaf7499e4d0eb7aa1a132a7e3ede4610d3fe1d533615267b633d28ddb21864ff287f0a0b4cdc5aecac83896c2d384bb8d0c2f6132ede7ac2 SHA512 25cae2c29186cbb0a0aa81cfc624b261ce86240ae5cd6c220e89a3a5cad43b4da35e4c981c93ee25443bea9afd6fb6422c25553de85bfa44bbf7a798f5fe6bb6
diff --git a/net-wireless/fern-wifi-cracker/fern-wifi-cracker-2.7.ebuild b/net-wireless/fern-wifi-cracker/fern-wifi-cracker-2.7.ebuild
deleted file mode 100644
index bfad48fb9..000000000
--- a/net-wireless/fern-wifi-cracker/fern-wifi-cracker-2.7.ebuild
+++ /dev/null
@@ -1,41 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_REQ_USE="sqlite"
-PYTHON_COMPAT=( python{2_6,2_7} )
-inherit python-r1 desktop
-
-DESCRIPTION="Wireless tool for WEP/WPA cracking and WPS keys recovery"
-HOMEPAGE="https://github.com/savio-code/fern-wifi-cracker/releases"
-SRC_URI="https://github.com/savio-code/fern-wifi-cracker/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="dict"
-
-DEPEND=""
-RDEPEND="dev-python/PyQt5
-	net-analyzer/macchanger
-	net-wireless/aircrack-ng
-	net-analyzer/scapy
-	dict? ( sys-apps/cracklib-words )
-	|| ( net-wireless/reaver-wps-fork-t6x net-wireless/reaver )"
-
-S="${WORKDIR}/${P}/Fern-Wifi-Cracker"
-
-src_prepare() {
-	#disable updates
-	sed -ie "s|self.connect(self.update_button|#self.connect(self.update_button|" core/fern.py
-	sed -ie "s|thread.start_new_thread(self.update_initializtion_check|#thread.start_new_thread(self.update_initializtion_check|" core/fern.py
-	eapply_user
-}
-
-src_install() {
-	insinto /usr/share/fern-wifi-cracker
-	doins -r *
-	domenu "${FILESDIR}"/fern-wifi-cracker.desktop
-	dosbin "${FILESDIR}"/fern-wifi-cracker
-}
diff --git a/net-wireless/fern-wifi-cracker/fern-wifi-cracker-2.8.ebuild b/net-wireless/fern-wifi-cracker/fern-wifi-cracker-2.8.ebuild
deleted file mode 100644
index 37089cef1..000000000
--- a/net-wireless/fern-wifi-cracker/fern-wifi-cracker-2.8.ebuild
+++ /dev/null
@@ -1,41 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_REQ_USE="sqlite"
-PYTHON_COMPAT=( python2_7 )
-inherit python-r1 desktop
-
-DESCRIPTION="Wireless tool for WEP/WPA cracking and WPS keys recovery"
-HOMEPAGE="https://github.com/savio-code/fern-wifi-cracker/releases"
-SRC_URI="https://github.com/savio-code/fern-wifi-cracker/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="dict"
-
-DEPEND=""
-RDEPEND="dev-python/PyQt5
-	net-analyzer/macchanger
-	net-wireless/aircrack-ng
-	net-analyzer/scapy
-	dict? ( sys-apps/cracklib-words )
-	|| ( net-wireless/reaver-wps-fork-t6x net-wireless/reaver )"
-
-S="${WORKDIR}/${P}/Fern-Wifi-Cracker"
-
-src_prepare() {
-	#disable updates
-	sed -ie "s|self.connect(self.update_button|#self.connect(self.update_button|" core/fern.py
-	sed -ie "s|thread.start_new_thread(self.update_initializtion_check|#thread.start_new_thread(self.update_initializtion_check|" core/fern.py
-	eapply_user
-}
-
-src_install() {
-	insinto /usr/share/fern-wifi-cracker
-	doins -r *
-	domenu "${FILESDIR}"/fern-wifi-cracker.desktop
-	dosbin "${FILESDIR}"/fern-wifi-cracker
-}
diff --git a/net-wireless/fern-wifi-cracker/fern-wifi-cracker-2.9.ebuild b/net-wireless/fern-wifi-cracker/fern-wifi-cracker-2.9.ebuild
new file mode 100644
index 000000000..3ca4146e2
--- /dev/null
+++ b/net-wireless/fern-wifi-cracker/fern-wifi-cracker-2.9.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+
+inherit eutils desktop python-r1 xdg-utils
+
+DESCRIPTION="Wireless tool for WEP/WPA cracking and WPS keys recovery"
+HOMEPAGE="https://github.com/savio-code/fern-wifi-cracker"
+SRC_URI="https://github.com/savio-code/fern-wifi-cracker/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dict policykit"
+
+DEPEND=""
+RDEPEND="${PYTHON_DEPS}
+	dev-python/PyQt5[gui,widgets,${PYTHON_USEDEP}]
+	net-analyzer/macchanger
+	net-wireless/aircrack-ng
+	net-analyzer/scapy
+	dict? ( sys-apps/cracklib-words )
+	|| ( net-wireless/reaver-wps-fork-t6x net-wireless/reaver )
+	policykit? ( sys-auth/polkit )"
+
+S="${WORKDIR}/${P}/Fern-Wifi-Cracker"
+
+pkg_setup() {
+	python_setup
+}
+
+src_prepare() {
+	# disable updates
+	sed \
+		-e "s|self.connect(self.update_button|#self.connect(self.update_button|" \
+		-i core/fern.py || die
+	sed \
+		-e "s|thread.start_new_thread(self.update_initializtion_check|#thread.start_new_thread(self.update_initializtion_check|" \
+		-i core/fern.py || die
+
+	python_fix_shebang "${S}"
+
+	default
+}
+
+src_install() {
+	insinto "/usr/share/fern-wifi-cracker"
+	doins -r *
+	python_optimize "${ED%/}/usr/share/fern-wifi-cracker"
+
+	dosym "../fern-wifi-cracker/resources/icon.png" "/usr/share/pixmaps/${PN}.png"
+
+	make_wrapper $PN \
+		"python2 /usr/share/fern-wifi-cracker/execute.py"
+
+	if use policykit; then
+		insinto "/usr/share/polkit-1/actions/"
+		doins "${FILESDIR}"/com.fern-pro.pkexec.fern-wifi-cracker.policy
+
+		make_desktop_entry \
+			"pkexec /usr/bin/${PN}" \
+			"Fern Wifi Cracker" \
+			"${PN}" \
+			"System;Security;X-Pentoo;X-Penetration;X-Wireless;"
+	else
+		make_desktop_entry \
+			"$PN" \
+			"Fern Wifi Cracker" \
+			"$PN" \
+			"System;Security;X-Pentoo;X-Penetration;X-Wireless;"
+	fi
+
+	dodoc ../README.md
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
diff --git a/net-wireless/fern-wifi-cracker/files/com.fern-pro.pkexec.fern-wifi-cracker.policy b/net-wireless/fern-wifi-cracker/files/com.fern-pro.pkexec.fern-wifi-cracker.policy
new file mode 100644
index 000000000..00d9cda69
--- /dev/null
+++ b/net-wireless/fern-wifi-cracker/files/com.fern-pro.pkexec.fern-wifi-cracker.policy
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE policyconfig PUBLIC
+ "-//freedesktop//DTD PolicyKit Policy Configuration 1.0//EN"
+ "http://www.freedesktop.org/standards/PolicyKit/1/policyconfig.dtd">
+<policyconfig>
+
+  <vendor>FERN</vendor>
+  <vendor_url>https://github.com/savio-code/fern-wifi-cracker</vendor_url>
+
+  <action id="com.fern-pro.pkexec.fern-wifi-cracker">
+    <description>Run fern-wifi-cracker as root</description>
+    <message>Authentication is required to run the fern-wifi-cracker</message>
+    <icon_name>fern-wifi-cracker</icon_name>
+    <defaults>
+      <allow_any>auth_admin</allow_any>
+      <allow_inactive>auth_admin</allow_inactive>
+      <allow_active>auth_admin</allow_active>
+    </defaults>
+    <annotate key="org.freedesktop.policykit.exec.path">/usr/bin/fern-wifi-cracker</annotate>
+    <annotate key="org.freedesktop.policykit.exec.allow_gui">true</annotate>
+  </action>
+
+</policyconfig>
diff --git a/net-wireless/fern-wifi-cracker/files/fern-wifi-cracker b/net-wireless/fern-wifi-cracker/files/fern-wifi-cracker
deleted file mode 100644
index 7055f508c..000000000
--- a/net-wireless/fern-wifi-cracker/files/fern-wifi-cracker
+++ /dev/null
@@ -1,3 +0,0 @@
-#!/bin/sh
-
-python2 /usr/share/fern-wifi-cracker/execute.py
diff --git a/net-wireless/fern-wifi-cracker/files/fern-wifi-cracker.desktop b/net-wireless/fern-wifi-cracker/files/fern-wifi-cracker.desktop
deleted file mode 100644
index 7ca0e29f1..000000000
--- a/net-wireless/fern-wifi-cracker/files/fern-wifi-cracker.desktop
+++ /dev/null
@@ -1,11 +0,0 @@
-[Desktop Entry]
-Name=Fern Wifi Cracker
-Version=1.0
-Exec=sudo -E /usr/sbin/fern-wifi-cracker
-Comment=
-Icon=/usr/share/fern-wifi-cracker/resources/icon.png
-Type=Application
-Terminal=false
-StartupNotify=true
-Categories=System;Security;X-Pentoo;X-Penetration;X-Wireless;
-OnlyShowIn=X-Pentoo;