maltego: 4.2.7.12570 bump

app-forensics/maltego/Manifest

@@ -1 +1,2 @@
 DIST maltego-4.2.6.12502.deb 106870342 BLAKE2B 4f25d03026ab19b269846d51721b0ce1f1a333a13f40f8f73eee06ae33f89108448bd6e48929cbffbae4722378876c50305812dc5ff038cf203f8ca0e6df3c3e SHA512 7244cffe2ac420a620710ca1f9d4ad0165e8d1e8266ce85c240fba0e24844666b268d4b8377b73ce6492aa1584c1c1315954f672aa4e57a28da8f84b989a2407
+DIST maltego-4.2.7.12570.deb 106870744 BLAKE2B 7e7c04bb854df5cd92847694c3cdb9949198e984864e7b4ec973147b711e02014d470552bb688975dd91a5e824d957cbbf24cee799ebec8aa30d00c8b807cadd SHA512 d6e794916e5a0fc726c45b7e5e75e28d0d76e32049323f7b2f8d5880b26db711852b3d2055b0389895087e3cd8053ba7d19f6f96099b19c313eae44b5d002de7

app-forensics/maltego/maltego-4.2.7.12570.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop eutils unpacker xdg-utils
+
+DESCRIPTION="Visualise, map and mine data"
+HOMEPAGE="https://www.paterva.com/"
+
+SHORT_V="$(ver_cut 1-3)"
+SRC_URI="https://www.paterva.com/malv${SHORT_V//./}/Maltego.v${PV}.deb -> ${P}.deb"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="Paterva-EULA"
+SLOT=0
+IUSE=""
+
+DEPEND="$(unpacker_src_uri_depends)"
+RDEPEND="virtual/jre"
+
+S="${WORKDIR}"
+
+src_prepare() {
+	# Cleanup
+	rm -fr usr/{share/doc,share/applications,bin} || die
+	default
+}
+
+src_install() {
+	doins -r *
+
+	fperms +x "/usr/share/${PN}/bin/${PN}"
+	dosym "../share/${PN}/bin/${PN}" "/usr/bin/${PN}"
+
+	make_wrapper \
+		"${PN}_memory_config" \
+		"/usr/bin/java -jar \"/usr/share/maltego/maltego-ui/modules/ext/Java_Config_App.jar\""
+
+	make_desktop_entry \
+		"${PN}" \
+		"Maltego" \
+		"${PN}" \
+		"Development;Utility;"
+
+	make_desktop_entry \
+		"${PN}_memory_config" \
+		"Maltego Memory Config" \
+		"${PN}" \
+		"Settings;"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}