go-text: forked Gentoo's outdated version, https://github.com/pentoo/pentoo-overlay/issues/1529

dev-go/go-text/Manifest

@@ -0,0 +1 @@
+DIST go-text-0.3.0.tar.gz 6102619 BLAKE2B c92e68014a8c157d76741c02acd708771d66bd3dda5b19285f5aa3e073e0fe3fccb9054744d35ea62b681ae4421bb7489238d6868f9314fb26f88e002287abe8 SHA512 bd60dfaa7d9dbfca171a3ba40b51f5663c01257cf3b12b618d35689a97ab2212d316d5716ff09681bf40b099f7e20a0e0df8cfc065699cb6a07ad1dc2e2bc189

dev-go/go-text/go-text-0.3.0.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGO_PN=golang.org/x/text/...
+
+if [[ ${PV} = *9999* ]]; then
+	inherit golang-vcs
+else
+	# fails to compile
+#	KEYWORDS="~amd64 ~arm ~x86"
+	EGIT_COMMIT="v${PV}"
+	SRC_URI="https://github.com/golang/text/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	inherit golang-vcs-snapshot
+fi
+inherit golang-build
+
+DESCRIPTION="Go text processing support"
+HOMEPAGE="https://godoc.org/golang.org/x/text"
+LICENSE="BSD"
+SLOT="0/${PVR}"
+IUSE=""
+DEPEND=">=dev-go/go-tools-0_pre20180817"
+RDEPEND=""
+
+src_compile() {
+	export -n GOCACHE XDG_CACHE_HOME #680946
+	# Create an isolated golibdir in order to avoid an
+	# "use of internal package not allowed" error when
+	# and older version is installed.
+	mkdir -p "${T}/golibdir/src/golang.org/x" || die
+	ln -s "$(get_golibdir_gopath)/src/golang.org/x/tools" "${T}/golibdir/src/golang.org/x/tools" || die
+	GOPATH="${S}:${T}/golibdir" \
+		go install -v -work -x ${EGO_BUILD_FLAGS} "${EGO_PN}" || die
+}
+
+src_install() {
+	golang_install_pkgs
+	exeopts -m0755 -p # preserve timestamps for bug 551486
+	exeinto "$(go env GOROOT)/bin"
+	doexe bin/*
+}
+
+src_test() {
+	GOPATH="${S}:${T}/golibdir" \
+		go test -v -work -x "${EGO_PN}" || die
+}