From a87d4f41edee3bd3a9c77c483526914dac14f11d Mon Sep 17 00:00:00 2001
From: blshkv <blshkv@pentoo.ch>
Date: Sun, 12 Jul 2020 12:18:43 +0800
Subject: [PATCH] openrazer: testing
 https://github.com/openrazer/openrazer/issues/1050

---
 sys-apps/openrazer/Manifest                  |  1 +
 sys-apps/openrazer/metadata.xml              |  8 ++
 sys-apps/openrazer/openrazer-20200712.ebuild | 90 ++++++++++++++++++++
 3 files changed, 99 insertions(+)
 create mode 100644 sys-apps/openrazer/Manifest
 create mode 100644 sys-apps/openrazer/metadata.xml
 create mode 100644 sys-apps/openrazer/openrazer-20200712.ebuild

diff --git a/sys-apps/openrazer/Manifest b/sys-apps/openrazer/Manifest
new file mode 100644
index 000000000..6f5dc8672
--- /dev/null
+++ b/sys-apps/openrazer/Manifest
@@ -0,0 +1 @@
+DIST openrazer-20200712.zip 329235 BLAKE2B 2ba97660d2d618b1f22fd29ff1cf7105f6d34746dbd8f6ff39a874ef03ef612d538b8a9e3b9a808b582336df75a289d590c8c57cae48698085bd70301cb3edb7 SHA512 a35834f2b8635afdeabf04da27f56e3cd71f15c0496bc9f16f6a01fdbb5d8df44a6c526d77961d5dba5a5cbd560e4eb4d1200c72afff5bbea511b845f4902c1d
diff --git a/sys-apps/openrazer/metadata.xml b/sys-apps/openrazer/metadata.xml
new file mode 100644
index 000000000..d65aa4208
--- /dev/null
+++ b/sys-apps/openrazer/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>blshkv@pentoo.ch</email>
+		<name>Anton Bolshakov</name>
+	</maintainer>
+</pkgmetadata>
diff --git a/sys-apps/openrazer/openrazer-20200712.ebuild b/sys-apps/openrazer/openrazer-20200712.ebuild
new file mode 100644
index 000000000..70a580306
--- /dev/null
+++ b/sys-apps/openrazer/openrazer-20200712.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1 linux-mod udev
+
+DESCRIPTION="Razer Drivers for Linux (Blackwidow TE 2014 test branch)"
+HOMEPAGE="https://openrazer.github.io/"
+#EGIT_BRANCH="feature_blackwidow_te_0x011c"
+HASH_COMMIT="50d373d59daa4dc92692085fabd4a01f23d31f6e"
+SRC_URI="https://github.com/openrazer/openrazer/archive/${HASH_COMMIT}.zip -> ${P}.zip"
+LICENSE="GPL-2"
+SLOT="0"
+
+RDEPEND="media-libs/libsdl2
+	media-libs/sdl2-image
+	sci-libs/fftw:3.0
+	dev-python/daemonize[$PYTHON_USEDEP]
+	dev-python/dbus-python[$PYTHON_USEDEP]
+	dev-python/notify2[$PYTHON_USEDEP]
+	dev-python/numpy[$PYTHON_USEDEP]
+	dev-python/pygobject:*[$PYTHON_USEDEP]
+	dev-python/python-evdev[$PYTHON_USEDEP]
+	dev-python/pyudev[$PYTHON_USEDEP]
+	dev-python/setproctitle[$PYTHON_USEDEP]
+	x11-misc/xautomation
+	x11-misc/xdotool"
+DEPEND="${RDEPEND}
+	app-misc/jq"
+
+S="${WORKDIR}/${PN}-${HASH_COMMIT}"
+
+BUILD_TARGETS="clean driver"
+BUILD_PARAMS="-C ${S} KERNELDIR=${KERNEL_DIR}"
+MODULE_NAMES="
+	razerkbd(kernel/driver/hid:${S}/driver)
+	razermouse(kernel/driver/hid:${S}/driver)
+	razermousemat(kernel/driver/hid:${S}/driver)
+	razerkraken(kernel/driver/hid:${S}/driver)
+	razeraccessory(kernel/driver/hid:${S}/driver)
+	razercore(kernel/driver/hid:${S}/driver)
+"
+
+src_prepare() {
+	default
+	# Fix jobserver unavailable
+	sed -i  -e '/daemon install$/s/make/$(MAKE)/' \
+	-e '/pylib install$/s/@make/$(MAKE)/' \
+	Makefile || die "sed failed for Makefile"
+	# Do not to install compressed files
+	sed -i '/gzip/d' daemon/Makefile || die "sed failed for daemon/Makefile"
+}
+
+src_compile() {
+	linux-mod_src_compile
+
+	compile_python() {
+		pushd pylib
+		distutils-r1_python_compile
+		popd
+
+		pushd daemon
+		distutils-r1_python_compile
+		popd
+	}
+	python_foreach_impl compile_python
+}
+
+src_install() {
+	linux-mod_src_install
+
+	udev_dorules install_files/udev/99-razer.rules
+	exeinto "$(get_udevdir)"
+	doexe install_files/udev/razer_mount
+
+	mypython_install() {
+		pushd pylib
+		distutils-r1_python_install
+		popd
+
+		pushd daemon
+		distutils-r1_python_install
+		emake DESTDIR="${D}" install-resources
+		popd
+	}
+	python_foreach_impl mypython_install
+}