binwalk: 2.2.0 bump

app-misc/binwalk/Manifest

@@ -0,0 +1 @@
+DIST binwalk-2.2.0.tar.gz 39594514 BLAKE2B 899a919647258759f16c2e59766b0db68d1a78edf0f5c3755c2a987695199a1851deed2820e6323d82d8af85d294a6f1fcafb655e5d2257d49b673ddae49da67 SHA512 5f3ed31c0b5f9ca3057f86e82787a73b06f9f73747b51dd72130a78e4d69cf43a0207bffc495d177e97811de5bf835b3d0507f314b7a0c960eddf6d1efe0f0f9

app-misc/binwalk/binwalk-2.2.0.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{6,7} )
+
+inherit distutils-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/ReFirmLabs/binwalk.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/ReFirmLabs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+DESCRIPTION="A tool for identifying files embedded inside firmware images"
+HOMEPAGE="https://github.com/ReFirmLabs/binwalk"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="graph squashfs ubifs yaffs"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep 'dev-python/backports-lzma[${PYTHON_USEDEP}]' python2_7)
+	dev-libs/capstone[python,${PYTHON_USEDEP}]
+	graph? ( dev-python/pyqtgraph[opengl,${PYTHON_USEDEP}] )
+	sys-apps/file[${PYTHON_USEDEP}]
+	squashfs? (
+		sys-fs/squashfs-tools:0
+		sys-fs/sasquatch
+	)
+	ubifs? ( sys-fs/ubi_reader )
+	yaffs? ( sys-fs/yaffshiv )"
+
+python_install_all() {
+	local DOCS=( API.md INSTALL.md README.md )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog "binwalk has many optional dependencies to automatically"
+		elog "extract/decompress data, see INSTALL.md for more details."
+	fi
+}

profiles/pentoo/base/package.accept_keywords/app-misc

@@ -1,20 +1,10 @@
+### Pentoo
+app-misc/binwalk
+=app-misc/gplaycli-3*
+sys-fs/sasquatch
+
+#Gentoo
 ~app-misc/crunch-3.6
-~app-misc/livecd-tools-2.0.3
-~app-misc/emelfm2-0.8.0
-~app-misc/flasm-1.63
-~app-misc/pax-utils-1.2.2
-app-misc/hivex
-app-misc/rtlamr
-
-~app-misc/binwalk-2.1.1
-~dev-python/pyliblzma-0.5.3
-=sys-fs/sasquatch-20160119
-
-app-misc/freediag
-app-misc/openodb
-
-=app-misc/gplaycli-3.26*
-
-=app-misc/mc-4.8.20-r2
-
+=app-misc/rtlamr-0.9*
+=app-misc/freediag-1*
 =app-misc/elasticsearch-5*