diff --git a/dev-python/backcall/backcall-0.1.0.ebuild b/dev-python/backcall/backcall-0.1.0.ebuild
index 30d94cc50..a5b810eb4 100644
--- a/dev-python/backcall/backcall-0.1.0.ebuild
+++ b/dev-python/backcall/backcall-0.1.0.ebuild
@@ -15,10 +15,9 @@ KEYWORDS="~amd64 ~x86"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 IUSE=""
 
 RDEPEND=""
-#>=dev-python/altgraph-0.15[${PYTHON_USEDEP}]"
 DEPEND="${RDEPEND}
 	dev-python/setuptools[${PYTHON_USEDEP}]"
diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 293d0bf6f..bdfa2faaa 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1 +1,2 @@
 DIST ipython-7.2.0.tar.gz 5112895 BLAKE2B 5df43ae6468187c883474e0d82b4ed3758accd37fdd039d2dc048ff1914b1dcc351d6d3f6404e7829ad68d62897a6be6a21e444067e7cf66270d2b25582ce0c7 SHA512 2236b620d66592d8cb453d03393d818c924f230dbc50f4b1a898fd746bf5c2dde345caa695024e508c81ee5e0e58452613bc31febf8e6df5485efb273327f95b
+DIST ipython-7.3.0.tar.gz 5115887 BLAKE2B ed880cae7eef000cab085e022bf33b0037fd7d8bbd4e3faba24af36ccdb8cbb7d73c4a35c10bd7729d29fbb350174f74b95758c8396fa46d92415d1583affdc0 SHA512 3fc0de6b7d1af9e48fd265df57ea2a51d73464d0d7d475cc6d84f219eb6f6705c843ceb2656ee2e8d8fd66d1dcc5b26ff6e7080a7560a981e97d206fd65ebacc
diff --git a/dev-python/ipython/ipython-7.2.0.ebuild b/dev-python/ipython/ipython-7.2.0.ebuild
index d225fa1cf..cedfd0fe5 100644
--- a/dev-python/ipython/ipython-7.2.0.ebuild
+++ b/dev-python/ipython/ipython-7.2.0.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 IUSE="doc examples matplotlib notebook nbconvert qt5 smp test"
 
 CDEPEND="
diff --git a/dev-python/ipython/ipython-7.3.0.ebuild b/dev-python/ipython/ipython-7.3.0.ebuild
new file mode 100644
index 000000000..cedfd0fe5
--- /dev/null
+++ b/dev-python/ipython/ipython-7.3.0.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="http://ipython.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc examples matplotlib notebook nbconvert qt5 smp test"
+
+CDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.10.0[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2.0.0[${PYTHON_USEDEP}] <dev-python/prompt_toolkit-2.1.0[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/pyparsing[${PYTHON_USEDEP}]
+	dev-python/backcall[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+	matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+"
+
+RDEPEND="${CDEPEND}
+	nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )
+"
+
+DEPEND="${CDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	virtual/python-typing[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+	)
+"
+
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? ( dev-python/ipyparallel[${PYTHON_USEDEP}] )
+"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+#DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/cythonmagic.py || die
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	pushd "${TEST_DIR}" >/dev/null || die
+	"${TEST_DIR}"/scripts/iptest || die
+	popd >/dev/null || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}