s3scanner-2.0.1.ebuild

net-analyzer/s3scanner/Manifest

@@ -1 +1,2 @@
 DIST s3scanner-1.0.0_p20190928.tar.gz 11971 BLAKE2B fcd5690a3232f87c9b088f29213dd859873bbb06d1c214837e983d72156c4d7e532fb5c13016d80f5f795f6b3dd832f723baadb8fece00694732bebbca5106c2 SHA512 b630241a09b689a77f96337dee82cf9581d27f94569d50008016d26dedb636c4f2a998b19b8e5ac8608b09d74e070627e5f95bfa5f5606a75826306cefe0ebfc
+DIST s3scanner-2.0.1.tar.gz 11971 BLAKE2B fcd5690a3232f87c9b088f29213dd859873bbb06d1c214837e983d72156c4d7e532fb5c13016d80f5f795f6b3dd832f723baadb8fece00694732bebbca5106c2 SHA512 b630241a09b689a77f96337dee82cf9581d27f94569d50008016d26dedb636c4f2a998b19b8e5ac8608b09d74e070627e5f95bfa5f5606a75826306cefe0ebfc

net-analyzer/s3scanner/s3scanner-2.0.1.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit eutils python-single-r1
+
+DESCRIPTION="Scan for open AWS S3 buckets and dump the contents"
+HOMEPAGE="https://github.com/sa7mon/S3Scanner"
+
+if [[ ${PV} = *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/sa7mon/S3Scanner.git"
+else
+	HASH_COMMIT="28f6ab4e04ddb55b6e0d2f517ced181d5111072a"
+
+	SRC_URI="https://github.com/sa7mon/S3Scanner/archive/${HASH_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		app-admin/awscli[${PYTHON_MULTI_USEDEP}]
+		dev-python/boto3[${PYTHON_MULTI_USEDEP}]
+		dev-python/coloredlogs[${PYTHON_MULTI_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_MULTI_USEDEP}]
+		dev-python/requests[${PYTHON_MULTI_USEDEP}]
+	')"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/S3Scanner-${HASH_COMMIT}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# Dirty hack to actually add a shebang to the file, so that we can then fix
+	# it using python_fix_shebang. Without a shebang, python_fix_shebang won't
+	# even work.
+	sed -i '1i#!/usr/bin/env python' "${PN}.py" || die
+	python_fix_shebang "${S}"
+}
+
+src_install() {
+	insinto /usr/share/${PN}
+	doins *.py sites.txt
+
+	python_optimize "${D}/usr/share/${PN}"
+
+	# s3scanner needs to be run from its installation directory.
+	make_wrapper $PN \
+		"${EPYTHON} /usr/share/${PN}/${PN}.py"
+
+	dodoc README.md Dockerfile
+}