eselect: push -r1 to rebuild the package (as a test) in order to fix 165 while ZC away. We need working eselect *now*

app-admin/eselect/Manifest

@@ -0,0 +1,2 @@
+DIST eselect-1.3.6.tar.xz 166976 SHA256 5a2d7c69ed6f668bee60a72f742a768fec4006b05255b0f79a4ebac86dbd0c2b SHA512 a1fb0f9216eb87365c19480b9a63b9d050630329e1e6697427408393b07a3e3c0165296dea48badfe97ab6a651fee7e3f312e640d7cb32626249de876d242d9c WHIRLPOOL 716db4e6d12088f77368f3115c1196b64b71b1d3931c728adc20ca4fb6cd719fc4da6e648df15531ff02d7200459577a606bac2e239286f8dc0f2c54eaa61d6b
+EBUILD eselect-1.3.6-r1.ebuild 1776 SHA256 fc70a83e4b3b817b234308d31476aac21c1ec8a9820bdbaaa62ddc6b032cb1cc SHA512 5a4440cc239e362ea82d8244d8b726574c50668a66efcf8d7650f8603fb3be673cede6217808d40910b4f57b9011817b1c961ed0ab548a0425f5e04db84d182e WHIRLPOOL 6d4b48b4d9693080eee3cb46323447f57fb49090b012e9d08fd72a8680d727e42ff566f0528e268d2de7a42a0b541ca08a750e44912daa670321dd515935b845

app-admin/eselect/eselect-1.3.6-r1.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect/eselect-1.3.6.ebuild,v 1.12 2013/09/05 19:57:28 ulm Exp $
+
+EAPI=4
+
+inherit eutils bash-completion-r1
+
+DESCRIPTION="Gentoo's multi-purpose configuration and management tool"
+HOMEPAGE="http://wiki.gentoo.org/wiki/Project:Eselect"
+SRC_URI="mirror://gentoo/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc emacs vim-syntax"
+
+RDEPEND="sys-apps/sed
+	|| (
+		sys-apps/coreutils
+		sys-freebsd/freebsd-bin
+		app-misc/realpath
+	)"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	doc? ( dev-python/docutils )"
+RDEPEND="!app-admin/eselect-news
+	${RDEPEND}
+	sys-apps/file
+	sys-libs/ncurses"
+
+PDEPEND="emacs? ( app-emacs/eselect-mode )
+	vim-syntax? ( app-vim/eselect-syntax )"
+
+src_compile() {
+	emake
+	use doc && emake html
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	newbashcomp misc/${PN}.bashcomp ${PN}
+	dodoc AUTHORS ChangeLog NEWS README TODO doc/*.txt
+	use doc && dohtml *.html doc/*
+
+	# needed by news module
+	keepdir /var/lib/gentoo/news
+	if ! use prefix; then
+		fowners root:portage /var/lib/gentoo/news
+		fperms g+w /var/lib/gentoo/news
+	fi
+}
+
+pkg_postinst() {
+	# fowners in src_install doesn't work for the portage group:
+	# merging changes the group back to root
+	if ! use prefix; then
+		chgrp portage "${EROOT}/var/lib/gentoo/news" \
+			&& chmod g+w "${EROOT}/var/lib/gentoo/news"
+	fi
+}