openvas-scanner: 6.0.0 bump

net-analyzer/openvas-scanner/Manifest

@@ -1 +1,2 @@
 DIST openvas-scanner-5.1.3.tar.gz 254159 BLAKE2B d90fa15e143ead53abce66f933a3a4cac327176cca0f23bd88fe771ed7726b1891784ae980644c8335e560d348753115e43cfae83af9704e2d1d02827163563f SHA512 5712ab275058877cfd656e268ed09c81db6617ae247c17092f1fcd037f692f2018daf21b09b82401f99a7361bb485f0e0f7d63f8ff2387839cfdd5a3aaf8424e
+DIST openvas-scanner-6.0.0.tar.gz 521615 BLAKE2B 3c5ab599203f7ee875227b5b08026edf60fd6d5274b0f4856d89a7c5b0b9875b4c789527284d5ad9f05a8f9cc1eaaa2324dbcd80dbb76118b0ca468900971415 SHA512 5d538476275ffc9f31f4f2934f2f57b741043728c9d107c07a88970f0d7a158baf3f40f1d8abb96dbb33f173c4fc21158be08c58de477857ff08cf897955c7b9

net-analyzer/openvas-scanner/openvas-scanner-6.0.0.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils systemd
+
+DESCRIPTION="A remote security scanner for Linux (OpenVAS-scanner)"
+HOMEPAGE="http://www.openvas.org/"
+SRC_URI="https://github.com/greenbone/openvas-scanner/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="snmp"
+
+RDEPEND="
+	app-crypt/gpgme
+	dev-libs/glib:2
+	dev-libs/libgcrypt:=
+	dev-libs/libksba
+	net-libs/gnutls
+	>=dev-libs/gvm-libs-10.0.0
+	net-libs/libpcap
+	net-libs/libssh
+	>=net-analyzer/openvas-libraries-8.0.2
+	!net-analyzer/openvas-plugins
+	!net-analyzer/openvas-server
+	snmp? ( net-analyzer/net-snmp )"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/bison
+	virtual/pkgconfig"
+
+PATCHES=(
+#	"${FILESDIR}"/${PN}-4.0.3-mkcertclient.patch
+	"${FILESDIR}"/${PN}-4.0.3-rulesdir.patch
+#	"${FILESDIR}"/${PN}-4.0.3-run.patch
+	)
+
+src_prepare() {
+	sed -e '/^install.*OPENVAS_CACHE_DIR.*/d' \
+		-i CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLOCALSTATEDIR="${EPREFIX}/var"
+		-DSYSCONFDIR="${EPREFIX}/etc"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	local my_pn="openvassd"
+
+	cmake-utils_src_install
+
+	insinto /etc/openvas
+	doins "${FILESDIR}"/${my_pn}.conf "${FILESDIR}"/${my_pn}-daemon.conf
+	dosym ../openvas/${my_pn}-daemon.conf /etc/conf.d/${my_pn}
+
+	insinto /etc/logrotate.d
+	doins "${FILESDIR}"/${my_pn}.logrotate
+
+	insinto /etc/
+	newins "${FILESDIR}"/${my_pn}-redis_40.conf redis_openvas.conf
+
+	dodoc "${FILESDIR}"/openvas-nvt-sync-cron
+
+	newinitd "${FILESDIR}"/${my_pn}.init ${my_pn}
+	systemd_newtmpfilesd "${FILESDIR}"/${my_pn}.tmpfiles.d ${my_pn}.conf
+	systemd_dounit "${FILESDIR}"/${my_pn}.service
+}