From 1d0a7ef6d31a9612b7150b38594e30297e0626ff Mon Sep 17 00:00:00 2001
From: Zero_Chaos <zerochaos-@users.noreply.github.com>
Date: Tue, 22 May 2012 19:44:00 +0000
Subject: [PATCH] wireshark: new stable bump

---
 net-analyzer/wireshark/Manifest               |   2 +
 net-analyzer/wireshark/wireshark-1.6.8.ebuild | 220 ++++++++++++++++++
 2 files changed, 222 insertions(+)
 create mode 100644 net-analyzer/wireshark/wireshark-1.6.8.ebuild

diff --git a/net-analyzer/wireshark/Manifest b/net-analyzer/wireshark/Manifest
index 0229d5faf..fde3f0add 100644
--- a/net-analyzer/wireshark/Manifest
+++ b/net-analyzer/wireshark/Manifest
@@ -14,6 +14,7 @@ DIST wireshark-1.6.4.tar.bz2 21464517 RMD160 9437c416a5963aee1c049c0275bdfd3edd7
 DIST wireshark-1.6.5.tar.bz2 21505901 RMD160 33c03112c1f97a94bc7306de918d882a29ada26d SHA1 42870fedaa6460681df30f6af9f18039a322b4a4 SHA256 151768199f9b50f5593b97025a33303df4d3b3983a203be89d8a1f5ba830bfcd
 DIST wireshark-1.6.6.tar.bz2 21527655 RMD160 27a3d7fa7f78350dabb00d3ee382c335f7e110ae SHA1 0b60fd7d117e78292548fd50d71f750a5dca8b37 SHA256 44dae5898209ece3803c6ce7c9bbb8544b565dd301e8890a6a2213f4a6a2172e
 DIST wireshark-1.6.7.tar.bz2 21524856 RMD160 20ced0176d0c2f7a856078d033ebf7ba531f7f57 SHA1 392c4f35cd8d16287ba9eba3afec226fcadd9746 SHA256 1e9d806d02ebfc3a70b948b4e82d19ba5bcde671eb229b18569149f95681f17b
+DIST wireshark-1.6.8.tar.bz2 21967111 RMD160 858ee1bdcf61658356c1acd386135eb071205dd6 SHA1 fb79058c66944581b822e4d8370848f953cfc9d4 SHA256 d4fbaffa4fd32543ed1d03b3097bf89a7d492e6d02e9bf8f8aa8a71281f3057f
 DIST wireshark-1.7.0.tar.bz2 22142779 RMD160 d65be41a4384b1754756b255330cc76e93cdd3af SHA1 e6da826833ece4efa0a257ea8aa8d5c7454dec62 SHA256 8b00ff9622d309d9848a078acafd59763dc341215b676b87fdeff98a7ccef89d
 DIST wireshark-1.7.1.tar.bz2 23309339 RMD160 bf5ee54aa38b1767979702c083914e17843a6ade SHA1 8f49b60c971ffd4857cb05afa82e22152261645f SHA256 ee61a1217919fd51427d8e15e001f120e99975d1e677c578db7caea51637a2ba
 EBUILD wireshark-1.4.7.ebuild 6637 RMD160 bc868901ecf0c492ab396d45fa0a5e711c04d224 SHA1 a6a81a9b0baf745f0d20cf680ee9e342cb07d0aa SHA256 3c84c5605bd450bb1043ded4dbfae1f5aaa4acf9053bc412ac1cc9666d9859ec
@@ -24,6 +25,7 @@ EBUILD wireshark-1.6.4.ebuild 6721 RMD160 c1bfc021232160dd1a63577ef9ffc31f124ccf
 EBUILD wireshark-1.6.5.ebuild 6639 RMD160 aee0b79d7ff9087cf8e9bb4794707ad243c4db45 SHA1 994a2aab21fead417e275a6e5843ea750490e4b4 SHA256 7cd32c2ed6661e89cb320e98e51a58e2ef523e266067fc2907c37c01277c4e48
 EBUILD wireshark-1.6.6.ebuild 6646 RMD160 3a8cdd4028d81b0c0876fcc4233336e943e01287 SHA1 7f23d00e1f9939c4928f92e69c88aad7e53a90a5 SHA256 00fc4577b282aa0dce8ed61c5620b8972e56a840e63ee650e82f73a33e848c1a
 EBUILD wireshark-1.6.7.ebuild 6644 RMD160 8aad8d208bb4abea6cac8edd3fdb54e718c524ac SHA1 88b430e7cb80c52c0c1ba2bf8020286f47bea443 SHA256 96269550bf8c1a71dd3b7e51b3f718f85917ce6ec69613b0357660a4f684445c
+EBUILD wireshark-1.6.8.ebuild 6644 RMD160 8aad8d208bb4abea6cac8edd3fdb54e718c524ac SHA1 88b430e7cb80c52c0c1ba2bf8020286f47bea443 SHA256 96269550bf8c1a71dd3b7e51b3f718f85917ce6ec69613b0357660a4f684445c
 EBUILD wireshark-1.7.0.ebuild 6664 RMD160 c26d9a4504a701cb142a4e9fd82e4efd75b21b7f SHA1 6df58206e581e55446b75e6d5fde064aefd17aa5 SHA256 59e1913bc61ccfb947baf97f0e775955bcd5b755d134d078b8667afe2af5d369
 EBUILD wireshark-1.7.1.ebuild 6664 RMD160 c26d9a4504a701cb142a4e9fd82e4efd75b21b7f SHA1 6df58206e581e55446b75e6d5fde064aefd17aa5 SHA256 59e1913bc61ccfb947baf97f0e775955bcd5b755d134d078b8667afe2af5d369
 MISC ChangeLog 43087 RMD160 9e98d25e3064ba15ec05b126dd8d4003443ecceb SHA1 8416fd3639a9459545df2c89000dd3fb1e2a8119 SHA256 8ff0ab790e1dab3bf722cc1149a8bbb0e1de69e1785c086ae8eae0a257712b3e
diff --git a/net-analyzer/wireshark/wireshark-1.6.8.ebuild b/net-analyzer/wireshark/wireshark-1.6.8.ebuild
new file mode 100644
index 000000000..6589fb30f
--- /dev/null
+++ b/net-analyzer/wireshark/wireshark-1.6.8.ebuild
@@ -0,0 +1,220 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.6.4.ebuild,v 1.8 2012/01/06 18:52:52 armin76 Exp $
+
+EAPI="3"
+PYTHON_DEPEND="python? 2"
+inherit libtool flag-o-matic eutils toolchain-funcs python autotools
+
+[[ -n ${PV#*_rc} && ${PV#*_rc} != ${PV} ]] && MY_P=${PN}-${PV/_} || MY_P=${P}
+DESCRIPTION="A network protocol analyzer formerly known as ethereal"
+HOMEPAGE="http://www.wireshark.org/"
+SRC_URI="http://www.wireshark.org/download/src/all-versions/${MY_P}.tar.bz2 \
+	btbb? ( mirror://sourceforge/libbtbb/libbtbb-0.6.tar.gz )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc x86 ~x86-fbsd"
+IUSE="adns ares btbb doc doc-pdf gtk ipv6 lua gcrypt geoip kerberos
+profile +pcap portaudio python +caps selinux smi ssl threads zlib"
+
+RDEPEND=">=dev-libs/glib-2.14:2
+	zlib? ( sys-libs/zlib
+		!=sys-libs/zlib-1.2.4 )
+	smi? ( net-libs/libsmi )
+	gtk? ( >=x11-libs/gtk+-2.4.0:2
+		x11-libs/pango
+		dev-libs/atk
+		x11-misc/xdg-utils )
+	ssl? ( net-libs/gnutls )
+	gcrypt? ( dev-libs/libgcrypt )
+	pcap? ( net-libs/libpcap )
+	caps? ( sys-libs/libcap )
+	kerberos? ( virtual/krb5 )
+	portaudio? ( media-libs/portaudio )
+	ares? ( >=net-dns/c-ares-1.5 )
+	!ares? ( adns? ( net-libs/adns ) )
+	geoip? ( dev-libs/geoip )
+	lua? ( >=dev-lang/lua-5.1 )
+	selinux? ( sec-policy/selinux-wireshark )"
+
+DEPEND="${RDEPEND}
+	doc? ( dev-libs/libxslt
+		dev-libs/libxml2
+		app-doc/doxygen
+		doc-pdf? ( dev-java/fop ) )
+	>=dev-util/pkgconfig-0.15.0
+	dev-lang/perl
+	sys-devel/bison
+	sys-apps/sed
+	sys-devel/flex
+	!!<net-analyzer/wireshark-1.6.0_rc1"
+
+S=${WORKDIR}/${MY_P}
+
+# borrowed from GSoC2010_Gentoo_Capabilities by constanze and flameyeys
+# @FUNCTION: fcaps
+# @USAGE: fcaps {uid:gid} {file-mode} {cap1[,cap2,...]} {file}
+# @RETURN: 0 if all okay; non-zero if failure and fallback
+# @DESCRIPTION:
+# fcaps sets the specified capabilities in the effective and permitted set of
+# the given file. In case of failure fcaps sets the given file-mode.
+fcaps() {
+	local uid_gid=$1
+	local perms=$2
+	local capset=$3
+	local path=$4
+	local res
+
+	chmod $perms $path && \
+	chown $uid_gid $path
+	res=$?
+
+	use caps || return $res
+
+	#set the capability
+	setcap "$capset=ep" "$path" &> /dev/null
+	#check if the capabilitiy got set correctly
+	setcap -v "$capset=ep" "$path" &> /dev/null
+	res=$?
+
+	if [ $res -ne 0 ]; then
+		ewarn "Failed to set capabilities. Probable reason is missed kernel support."
+		ewarn "Kernel must have <FS>_FS_SECURITY enabled where <FS> is the filesystem"
+		ewarn "to store ${path} (e.g. EXT3_FS_SECURITY). For kernels version before"
+		ewarn "2.6.33_rc1 SECURITY_FILE_CAPABILITIES must be enabled as well."
+		ewarn
+		ewarn "Falling back to suid now..."
+		chmod u+s ${path}
+	fi
+	return $res
+}
+
+pkg_setup() {
+	if ! use gtk; then
+		ewarn "USE=-gtk disables gtk-based gui called wireshark."
+		ewarn "Only command line utils will be built available"
+	fi
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+	# Add group for users allowed to sniff.
+	enewgroup wireshark
+}
+
+src_prepare() {
+	use btbb && mv "${WORKDIR}"/libbtbb-0.6/wireshark/plugins/btbb "${S}"/plugins/
+	use btbb && epatch "${FILESDIR}/${PN}-1.6-btbb.patch"
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	if [[ $(gcc-major-version) -lt 3 ||
+		( $(gcc-major-version) -eq 3 &&
+			$(gcc-minor-version) -le 4 ) ]] ; then
+		die "Unsupported compiler version, please upgrade."
+	fi
+
+	if use ares && use adns; then
+		elog "You asked for both, ares and adns, but we can use only one of them."
+		elog "c-ares supersedes adns resolver thus using c-ares (ares USE flag)."
+		myconf="$(use_with ares c-ares) --without-adns"
+	else
+		myconf="$(use_with adns) $(use_with ares c-ares)"
+	fi
+
+	# profile and pie are incompatible #215806, #292991
+	if use profile; then
+		ewarn "You've enabled the 'profile' USE flag, building PIE binaries is disabled."
+		ewarn "Also ignore \"unrecognized option '-nopie'\" gcc warning #358101."
+		append-flags $(test-flags-CC -nopie)
+	fi
+
+	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
+	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
+	if use kerberos; then
+		case `krb5-config --libs` in
+			*-lcrypto*)
+				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
+				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
+				ewarn "license and the GPL, so do your check before distributing such package."
+				myconf+=" --with-ssl"
+				;;
+		esac
+	fi
+
+	# Hack around inability to disable doxygen/fop doc generation
+	use doc || export ac_cv_prog_HAVE_DOXYGEN=false
+	use doc-pdf || export ac_cv_prog_HAVE_FOP=false
+
+	# dumpcap requires libcap, setuid-install requires dumpcap
+	econf $(use_enable gtk wireshark) \
+		$(use_enable profile profile-build) \
+		$(use_with ssl gnutls) \
+		$(use_with gcrypt) \
+		$(use_enable ipv6) \
+		$(use_enable threads) \
+		$(use_with lua) \
+		$(use_with kerberos krb5) \
+		$(use_with smi libsmi) \
+		$(use_with zlib) \
+		$(use_with geoip) \
+		$(use_with portaudio) \
+		$(use_with python) \
+		$(use_with caps libcap) \
+		$(use_with pcap) \
+		$(use_with pcap dumpcap-group wireshark) \
+		$(use pcap && use_enable caps setcap-install) \
+		$(use pcap && use_enable !caps setuid-install) \
+		--sysconfdir="${EPREFIX}"/etc/wireshark \
+		--disable-extra-gcc-checks \
+		${myconf}
+}
+
+src_compile() {
+	emake || die
+	use doc && cd docbook && { emake || die; }
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	if use doc; then
+		dohtml -r docbook/{release-notes.html,ws{d,u}g_html{,_chunked}}
+		if use doc-pdf; then
+			insinto /usr/share/doc/${PF}/pdf/
+			doins docbook/{{developer,user}-guide,release-notes}-{a4,us}.pdf || die
+		fi
+	fi
+
+	# FAQ is not required as is installed from help/faq.txt
+	dodoc AUTHORS ChangeLog NEWS README{,.bsd,.linux,.macos,.vmware} \
+		doc/{randpkt.txt,README*}
+
+	insinto /usr/include/wiretap
+	doins wiretap/wtap.h || die
+
+	if use gtk; then
+		for c in hi lo; do
+			for d in 16 32 48; do
+				insinto /usr/share/icons/${c}color/${d}x${d}/apps
+				newins image/${c}${d}-app-wireshark.png wireshark.png
+			done
+		done
+		domenu wireshark.desktop || die
+	fi
+	use pcap && chmod o-x "${ED}"/usr/bin/dumpcap #357237
+}
+
+pkg_postinst() {
+	if use caps && use pcap; then
+		fcaps 0:wireshark 550 cap_net_raw,cap_net_admin "${EROOT}"/usr/bin/dumpcap
+	fi
+	echo
+	ewarn "NOTE: To run wireshark as normal user you have to add yourself to"
+	ewarn "the wireshark group. This security measure ensures that only trusted"
+	ewarn "users are allowed to sniff your traffic."
+	echo
+}