Merge pull request #2061 from blshkv/master

grpcio

dev-python/grpcio-tools/Manifest

@@ -1 +1,2 @@
 DIST grpcio-tools-1.62.0.tar.gz 4613875 BLAKE2B 60c8d7c38f10a80ed5b420ecab312ea6f5ad384245194c4f6726783385d443c6354306bbef604230d3a81e9f2cc6885f76eb6a5beae4733279d6210c3fe6603d SHA512 c1691a705cea54056850e98caff37025e551b165b4042f6cab856319805e9507b9aaac5ceea35641f62ce619274faac735e4d2002d36e22b1ce22cf96269dc58
+DIST grpcio_tools-1.65.2.tar.gz 5028990 BLAKE2B 96e141c620c6c7819dd9889263b0fe08f4abc93bbad50863e0513f85c4a140539e8aaef923fe502098234f1426a348c4b5b211998c7fcd952d280239a760ff8a SHA512 2b08fadaac4efda63bec88e1575062a6e88d2a187ee23cbad58eeed41612660dc9a2abfd37cf9b8025a287bdb5c7a82fb59d652391d6f026ac31d1a7487f0282

dev-python/grpcio-tools/grpcio-tools-1.65.2.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+PYTHON_COMPAT=( python3_{9..12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 multiprocessing prefix pypi
+
+DESCRIPTION="Protobuf code generator for gRPC"
+HOMEPAGE="https://grpc.io"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	~dev-python/grpcio-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/protobuf-python-5.26.1[${PYTHON_USEDEP}]
+	<dev-python/protobuf-python-6[${PYTHON_USEDEP}]
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	hprefixify setup.py
+
+	# use system protobuf
+	sed -r -i \
+		-e '/^CC_FILES=\[/,/\]/{/^CC_FILES=\[/n;/\]/!d;}' \
+		-e '/^CC_INCLUDES=\[/,/\]/{/^CC_INCLUDES=\[/n;/\]/!d;}' \
+		-e "s@^(PROTO_INCLUDE=')[^']+'@\1/usr/include'@" \
+		-e '/^PROTOBUF_SUBMODULE_VERSION=/d' \
+		protoc_lib_deps.py
+
+	# fix the include path
+	ln -s ../../../.. grpc_root
+}
+
+python_configure_all() {
+	export GRPC_PYTHON_BUILD_WITH_CYTHON=1
+	export GRPC_PYTHON_BUILD_EXT_COMPILER_JOBS="$(makeopts_jobs)"
+}

dev-python/grpcio/Manifest

@@ -1 +1,2 @@
 DIST grpcio-1.62.0.tar.gz 26315723 BLAKE2B a49156538644f66af7a569c0a91eb48a5d15177a8aa7c4410c4f8ea54f18893f2ca6d10a522a73f4e4d8950372aa35e8bc909f062b89db0a40e8765cebd43a23 SHA512 cd54cf3c2d296faca2f7b4eb13385e407aa09be752234585cb71b53afd1bc48fd8aca01eac1a4e2583a0ef07a902b84c887413d6678210c5f38a91a13960e826
+DIST grpcio-1.65.2.tar.gz 12259424 BLAKE2B e689199b605f742fdf89f18d0c8844f4b66c65960b4bd959f3ac6b000389fc196e9a1a6acd9d3a1a7323a93e45082d09bf6aae210dbcf445040ff177f0f26581 SHA512 c4c90b9bfc910cf2a81d52699da11c2312bc198e41f8babd2aaa3479b990dd031522f55abd3c7363ca64a383d9589724f503182b807371f25f7c2ce9823d3b6d

dev-python/grpcio/grpcio-1.65.2.ebuild

@@ -0,0 +1,47 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..12} )
+
+inherit distutils-r1 multiprocessing prefix pypi
+
+DESCRIPTION="High-performance RPC framework (python libraries)"
+HOMEPAGE="https://grpc.io"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-libs/openssl-1.1.1:0=[-bindist(-)]
+	>=dev-python/protobuf-python-5.26.1[${PYTHON_USEDEP}]
+	>=dev-libs/re2-0.2024.07.02:=
+	net-dns/c-ares:=
+	sys-libs/zlib:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	hprefixify setup.py
+}
+
+python_configure_all() {
+	export GRPC_BUILD_WITH_BORING_SSL_ASM=0
+	export GRPC_PYTHON_DISABLE_LIBC_COMPATIBILITY=1
+	export GRPC_PYTHON_BUILD_SYSTEM_CARES=1
+	export GRPC_PYTHON_BUILD_SYSTEM_OPENSSL=1
+	export GRPC_PYTHON_BUILD_SYSTEM_RE2=0
+	export GRPC_PYTHON_BUILD_SYSTEM_ABSL=1
+	export GRPC_PYTHON_BUILD_SYSTEM_ZLIB=1
+	export GRPC_PYTHON_BUILD_WITH_CYTHON=1
+	export GRPC_PYTHON_BUILD_EXT_COMPILER_JOBS="$(makeopts_jobs)"
+}