soapysdr: v0.6.0 bump

net-wireless/soapysdr/Manifest

@@ -1 +1,2 @@
 DIST soapysdr-0.5.4.tar.gz 106605 SHA256 b8e32f6046cb7b9a49e377a9271b5e1e6ac6d93f5e67dd39c253d91c7e4d3519 SHA512 7cf3d0360165be7ab5be3619dfaf980961a897e40ab1c6f1bc934e67b02b4afe53c2656adcec8d43ecf4ce28e97d18a9c544d972cc0f67addae447d86e633aaa WHIRLPOOL afb53103bc8892d8142b7ffd32137f2d4bd356791088d52214c9f6f5d7ea5bbf304cc08d0cc630d55b9e7f113f7d438075c940bb8c29adf0d680c3fbc194e4f0
+DIST soapysdr-0.6.0.tar.gz 112061 SHA256 54b0f84edbd52a10073444d9124f41b622194744d136ea77e25c8b883e65abf9 SHA512 19b65c4d8c052ed40ff22c27511bb3b366a1912cb07930cbfe21808edc67b1fd6d10c96cd597dca988f8a2bff3611bb8345432d91d55032daeeba700cf1303d1 WHIRLPOOL 926b2f22496a201d497832e3b199013072b5779cbdec8f07b0c29242b73196ba8852eabee93f90b4d582c6e7b2817215db08c26e24fa9b1709d8dab44c3757be

net-wireless/soapysdr/soapysdr-0.6.0.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit cmake-utils python-r1
+
+DESCRIPTION="vendor and platform neutral SDR support library"
+HOMEPAGE="http://github.com/pothosware/SoapySDR"
+
+if [ "${PV}" = "9999" ]; then
+	EGIT_REPO_URI="https://github.com/pothosware/SoapySDR.git"
+	EGIT_CLONE_TYPE="shallow"
+	KEYWORDS=""
+	inherit git-r3
+else
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://github.com/pothosware/SoapySDR/archive/soapy-sdr-${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/SoapySDR-soapy-sdr-"${PV}"
+fi
+
+LICENSE="Boost-1.0"
+SLOT="0"
+
+IUSE="bladerf hackrf python rtlsdr uhd"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	python? ( dev-lang/swig:0 )
+"
+PDEPEND="bladerf? ( net-wireless/soapybladerf )
+		hackrf? ( net-wireless/soapyhackrf )
+		rtlsdr? ( net-wireless/soapyrtlsdr )
+		uhd? ( net-wireless/soapyuhd )"
+
+src_prepare() {
+	use python && python_copy_sources
+	default
+}
+
+src_configure() {
+	configuration() {
+		local mycmakeargs=(
+			-DENABLE_PYTHON=$(usex python)
+		)
+		if python_is_python3; then
+			mycmakeargs+=( -DBUILD_PYTHON3=ON
+				       -DENABLE_PYTHON3=ON
+			)
+		else
+			mycmakeargs+=( -DBUILD_PYTHON3=OFF
+				       -DENABLE_PYTHON3=OFF
+			)
+		fi
+		cmake-utils_src_configure
+	}
+	if use python; then
+		python_foreach_impl configuration
+	else
+		CMAKE_IN_SOURCE_BUILD=1
+		mycmakeargs+=( -DBUILD_PYTHON3=OFF
+			-DENABLE_PYTHON3=OFF
+			-DBUILD_PYTHON=OFF
+			-DENABLE_PYTHON=OFF
+		)
+		cmake-utils_src_configure
+	fi
+}
+
+src_compile() {
+	compilation() {
+		cmake-utils_src_make
+	}
+	use python && python_foreach_impl compilation || compilation
+}
+
+src_install() {
+	installation() {
+		cmake-utils_src_install DESTDIR="${ED}"
+		use python && python_optimize
+	}
+	use python && python_foreach_impl installation || installation
+}