# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{7..9} )
DISTUTILS_USE_SETUPTOOLS=rdepend
inherit distutils-r1

DESCRIPTION="CTF framework and exploit development library"
HOMEPAGE="https://github.com/Gallopsled/pwntools"
SRC_URI="https://github.com/Gallopsled/pwntools/archive/${PV}.tar.gz -> ${P}.tar.gz"

#Most is under an MIT license, but a few pieces are under GPL or a BSD 2-clause licence
LICENSE="MIT"
SLOT="0"
#wait for capstone (ROPgadget dep) to become stable
KEYWORDS="~amd64 ~x86"

RDEPEND="${PYTHON_DEPS}
	>=dev-python/paramiko-1.15.2[${PYTHON_USEDEP}]
	dev-python/mako[${PYTHON_USEDEP}]
	dev-python/pyelftools[${PYTHON_USEDEP}]
	dev-libs/capstone[python,${PYTHON_USEDEP}]
	app-exploits/ROPgadget[${PYTHON_USEDEP}]
	dev-python/pyserial[${PYTHON_USEDEP}]
	dev-python/requests[${PYTHON_USEDEP}]
	dev-python/pygments[${PYTHON_USEDEP}]
	dev-python/PySocks[${PYTHON_USEDEP}]
	dev-python/python-dateutil[${PYTHON_USEDEP}]
	dev-python/packaging[${PYTHON_USEDEP}]
	dev-python/psutil[${PYTHON_USEDEP}]
	>=dev-python/intervaltree-3.0[${PYTHON_USEDEP}]
	dev-python/sortedcontainers[${PYTHON_USEDEP}]
	dev-util/unicorn[python,unicorn_targets_x86(+),${PYTHON_USEDEP}]
	dev-python/six[${PYTHON_USEDEP}]
	dev-python/rpyc[${PYTHON_USEDEP}]
	dev-python/colored-traceback[${PYTHON_USEDEP}]
	"
DEPEND="${RDEPEND}"

PATCHES=(
	"${FILESDIR}/${PN}-4.0.0_do_not_mess_with_docs.patch"
	"${FILESDIR}/${PN}-4.1.0_update_deps.patch"
)
