# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..14} )

inherit distutils-r1 pypi

DESCRIPTION="Task scheduling and blocked algorithms for parallel processing"
HOMEPAGE="
	https://www.dask.org/
	https://github.com/dask/dask/
	https://pypi.org/project/dask/
"

LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 ~arm64 ~x86"

RDEPEND="
	>=dev-python/click-8.1[${PYTHON_USEDEP}]
	>=dev-python/cloudpickle-1.5.0[${PYTHON_USEDEP}]
	>=dev-python/fsspec-2021.09.0[${PYTHON_USEDEP}]
	>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
	>=dev-python/partd-1.4.0[${PYTHON_USEDEP}]
	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
	>=dev-python/toolz-0.10.0[${PYTHON_USEDEP}]
	$(python_gen_cond_dep '
		>=dev-python/importlib-metadata-4.13.0[${PYTHON_USEDEP}]
	' 3.{10..11})
"
BDEPEND="
	dev-python/toolz[${PYTHON_USEDEP}]
	test? (
		dev-python/moto[${PYTHON_USEDEP}]
		dev-python/numexpr[${PYTHON_USEDEP}]
		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
		dev-python/scipy[${PYTHON_USEDEP}]
	)
"

#	>=dev-python/importlib_metadata-4.13.0[${PYTHON_USEDEP}]
#	#dropped with py3.9

distutils_enable_tests pytest

EPYTEST_DESELECT=(
	# more tests relying on -Werror
	"dask/array/tests/test_overlap.py::test_map_overlap_no_depth[None]"
	dask/array/tests/test_random.py::test_RandomState_only_funcs
	# TODO
	dask/array/tests/test_reductions.py::test_mean_func_does_not_warn
	dask/tests/test_config.py::test__get_paths
	dask/array/tests/test_linalg.py::test_solve_assume_a
	"dask/dataframe/tests/test_dataframe.py::test_repartition_npartitions[<lambda>0-float-5-1-True]"
	"dask/dataframe/tests/test_dataframe.py::test_repartition_npartitions[<lambda>1-float-5-1-True]"
	# require sqlalchemy<2.0
	dask/dataframe/io/tests/test_sql.py
)

src_prepare() {
	# fails with sqlalchemy-2.0, even though we don't use it x_x
	#sed -i -e '/RemovedIn20Warning/d' setup.cfg || die
	distutils-r1_src_prepare
}

python_test() {
	epytest -p no:flaky -m "not network"
}
